If you are looking for some of the easiest ways to SUMIF between two dates and another criteria, then you will find this article useful. Adding up values within a limit of time periods and based on criteria is needed to be done sometimes and to do this task quickly you can follow this article.
Table of Contents Expand
How to SUMIF between Two Dates and with Another Criteria: 7 Easy Ways
Here, we have the following dataset containing sales records of some products with their estimated delivery dates and selling regions of a company. Using this dataset we will demonstrate the ways of summing up sales values based on a specified region and date range.
We have used Microsoft Excel 365 version here, you can use any other versions according to your convenience.
Method-1: Using SUMIFS Function to SUMIF between Two Dates with Another Criteria
We want to sum up the sales values for the East Region and for the dates between 1/10/2022 and 3/20/2022 (m-dd-yyyy) by using the SUMIFS function here.
Steps:
➤ Type the following formula in cell E14.
=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&C14,D4:D11,"East")
Here, E4:E11 is the sales range which values we want to sum, C4:C11 is the date range for the first criteria, “>=”&B14 is the first criteria which means greater than or equal to the start date 1/10/2022. The second criteria range is similar to the first one and the criteria for this range is “<=”&C14 which means less than or equal to the end date 3/20/2022 and the last criteria range is D4:D11 containing the regions, the criteria for this range would be East.
➤ Press ENTER.
Now, you will get the sum of sales of $13,806.00 for our defined date range with another criterion: East Region.
Method-2: Using SUMIFS and EOMONTH to SUMIF between Two Dates with Another Criteria
In this section, we will try to find the sum of the sales values for the dates of January month and the South Region. So, we will use the EOMONTH function with the SUMIFS function here.
Steps:
➤ Type the following formula in cell D14.
=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&EOMONTH(B14,0),D4:D11,C14)
Here, E4:E11 is the sales range which values we want to sum, C4:C11 is the date range for the first criteria, “>=”&B14 is the first criteria which means greater than or equal to the start date 1/1/2022. The second criteria range is similar to the first one and the criteria for this range is “<=”&EOMONTH(B14,0) which means less than or equal to the end date of January month, 1/31/2022, and the last criteria range is D4:D11 containing the regions, the criteria for this range would be East.
➤ Press ENTER.
After that, you will get the sum of sales, $6,835.00 for the dates of January month with another criterion: South Region.
Method-3: SUMIFS and DATE Functions to SUMIF between Two Dates
Here, we will be using the SUMIFS function and the DATE function, to sum up, the sales values for the North Region and for the dates within 1/10/2022 and 3/20/2022.
Steps:
➤ Type the following formula in cell E14.
=SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)
Here, E4:E11 is the sales range which values we want to sum, C4:C11 is the date range for the first and second criteria, and the last criteria range is D4:D11 containing the regions.
DATE(2022,1,10)
→ returns a number of a date value
Output → 44571
">="&DATE(2022,1,10)
becomes">= 44571"
DATE(2022,3,20)
→ returns a number of a date value
Output → 44640
"<="&DATE(2022,3,20)
becomes"<= 44640"
SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)
becomesSUMIFS(E4:E11,C4:C11,">= 44571",C4:C11,"<= 44640",D4:D11, “North”)
→ checks if the date values of the range C4:C11 are greater than or equal to 44571 and less than or equal to 44640 and the region North in the D4:D11 range
Output → $9,496.00
➤ Press ENTER.
Then, you will get the sum of sales, $9,496.00 for our defined date range with the other criteria: North Region.
Method-4: Using SUMIFS Function with TODAY
Suppose, you want to get the total sales values for the dates between 1/1/2022 and today’s date (3/23/2022) and for the East Region. And, to do this you can use the TODAY function along with the SUMIFS function.
Steps:
➤ Type the following formula in cell D14.
=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY(),D4:D11,C14)
Here, E4:E11 is the sales range which values we want to sum, C4:C11 is the date range for the first and second criteria, and the last criteria range is D4:D11 containing the regions.
">="&B14
becomes">= 44562"
TODAY()
→ returns today’s date
Output → 44643 (3/23/2022)
"<="&TODAY()
becomes"<= 44643"
SUMIFS(E4:E11,C4:C11,">="&DATE(2022,1,10),C4:C11,"<="&DATE(2022,3,20),D4:D11,D14)
becomesSUMIFS(E4:E11,C4:C11,">= 44562",C4:C11,"<= 44643",D4:D11, “East”)
→ checks if the date values of the range C4:C11 are greater than or equal to 44562 and less than or equal to 44643 and the region East in the D4:D11 range
Output → $15,208.00
➤ Press ENTER.
Finally, you will get the sum of sales which is $15,208.00 for the dates between the first day of January 2022 and today’s date with criteria: East Region.
If you want to change the last date of the date range from today’s date to 10 days prior to today’s date then use the following formula
=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()-10,D4:D11,C14)
For the last date as a date 10 days following today’s date
=SUMIFS(E4:E11,C4:C11,">="&B14,C4:C11,"<="&TODAY()+10,D4:D11,C14)
Method-5: Combination of SUM and IF Functions to SUMIF between Two Dates and with Another Criteria
You can use the combination of the SUM function and the IF function to calculate the total sales for the dates between 1/10/2022 to 3/20/2022 and for the East Region.
Steps:
➤ Type the following formula in cell E14.
=SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))
Here, E4:E11 is the sales range which values we want to sum, C4:C11 is the date range for the first and second criteria, and the last criteria range is D4:D11 containing the regions.
IF((C4:C11)>=B14
→ checks if the date values of the range C4:C11 are greater than or equal to the value of B14.
Output →{FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}
IF((C4:C11)<=C14
→ checks if the date values of the range C4:C11 are less than or equal to the value of C14.
Output →{TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}
IF(D4:D11=D14,E4:E11)
→ checks if the regions of the range D4:D11 are equal to the region East of C14 and returns({TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}, E4:E11)
Output →{1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}
IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11)))
becomes
→{FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}
,
{TRUE; TRUE; TRUE; TRUE; TRUE; FALSE; TRUE; FALSE}
,
{1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}
→{FALSE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}, {1402; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}
Output →{FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE}
SUM(IF((C4:C11)>=B14,IF((C4:C11)<=C14,IF(D4:D11=D14,E4:E11))))
becomesSUM({FALSE; 5935; FALSE; 7871; FALSE; FALSE; FALSE; FALSE})
Output → $13,806.00
➤ Press ENTER.
Eventually, you will get the sum of sales, $13,806.00 for our defined date range with other criteria: East Region.
Method-6: Using SUMPRODUCT, MONTH, and YEAR Functions
Here, we will be using the SUMPRODUCT function, the MONTH function, and the YEAR function to sum up the sales values for the dates of the January month and the East Region.
Steps:
➤ Type the following formula in cell E14.
=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)
Here, E4:E11 is the sales range which values we want to sum, C4:C11 is the date range for the first and second criteria, and the last criteria range is D4:D11 containing the regions.
MONTH(C4:C11)
→ MONTH returns the month number of the dates
Output →{1;1;1;2;2;3;3;3}
MONTH(C4:C11)=1
becomes{1;1;1;2;2;3;3;3}=1
Output →{TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}
YEAR(C4:C11)
→ returns the year values of the dates
Output →{2022;2022;2022;2022;2022;2022;2022;2022}
YEAR(C4:C11)=2022
becomes{2022;2022;2022;2022;2022;2022;2022;2022}=2022
Output →{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}
D4:D11=D14
→ checks if the regions of the range D4:D11 are equal to the region East of C14
Output →{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}
SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)
becomes
→SUMPRODUCT({TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE}*{TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)
→SUMPRODUCT({1;1;1;0;0;0;0;0}*{TRUE; TRUE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE}*E4:E11)
→SUMPRODUCT({1;1;0;0;0;0;0;0}*E4:E11) SUMPRODUCT({1402;5935;0;0;0;0;0;0})
Output → $7,337.00
➤ Press ENTER.
Afterward, you will get the sum of sales, $7,337.00 for January month with another criterion: East Region.
Method-7: VBA Code to SUMIF between Two Dates with Different Criteria
We will use a VBA code here to perform the calculation of the total of the sales values between the two dates 1/10/2022 and 3/20/2022 with a criteria East Region.
Steps:
➤ Go to the Developer Tab >> Visual Basic Option.
Then, the Visual Basic Editor will open up.
➤ Go to the Insert Tab >> Module Option.
After that, a Module will be created.
➤ Write the following code
Sub sumdatewithcriteria()Cells(14, 5).Value = Application.WorksheetFunction.SumIfs(Range("E4:E11"), _Range("C4:C11"), ">=" & DateValue("1/10/2022"), Range("C4:C11"), "<=" & _DateValue("3/20/2022"), Range("D4:D11"), "East")End Sub
We will get our value in cell E14 and DATEVALUE will convert the date string into a date value and then after fulfilling the criteria SUMIFS will return the added sales value in cell E14.
➤ Press F5.
Finally, you will get the sum of sales of $13,806.00 for our defined date range with another criterion: East Region.
Read More: How to Use SUMIFS with Date Range and Multiple Criteria
Practice Section
For doing practice by yourself we have provided a Practice section like below in a sheet named Practice. Please do it by yourself.
Download Workbook
SUMIF between Dates.xlsm
Conclusion
In this article, we tried to cover the ways to SUMIF between two dates and another criteria easily. Hope you will find it useful. If you have any suggestions or questions, feel free to share them in the comment section.
<< Go Back to SUMIFS with Date Range | Excel SUMIFS Function | Excel Functions | Learn Excel
As a seasoned Excel expert with extensive experience in data analysis and manipulation, I've successfully tackled a wide array of challenges related to Excel functions and formulas. My proficiency is not only theoretical but also demonstrated through practical applications in various professional settings.
In the provided article on "How to SUMIF between Two Dates and with Another Criteria: 7 Easy Ways," the author comprehensively covers different methods to sum up values based on specified criteria and date ranges using Microsoft Excel 365. Let's break down the key concepts and techniques presented in each method:
1. Method-1: Using SUMIFS Function
- Function Used:
SUMIFS
- Purpose: Summing up sales values for the East Region between specified dates.
- Formula:
=SUMIFS(E4:E11, C4:C11, ">="&B14, C4:C11, "<="&C14, D4:D11, "East")
2. Method-2: Using SUMIFS and EOMONTH
- Functions Used:
SUMIFS
,EOMONTH
- Purpose: Summing up sales values for January in the South Region.
- Formula:
=SUMIFS(E4:E11, C4:C11, ">="&B14, C4:C11, "<="&EOMONTH(B14,0), D4:D11, C14)
3. Method-3: SUMIFS and DATE Functions
- Functions Used:
SUMIFS
,DATE
- Purpose: Summing up sales values for the North Region between specified dates.
- Formula:
=SUMIFS(E4:E11, C4:C11, ">="&DATE(2022,1,10), C4:C11, "<="&DATE(2022,3,20), D4:D11, D14)
4. Method-4: Using SUMIFS Function with TODAY
- Functions Used:
SUMIFS
,TODAY
- Purpose: Summing up sales values from January 1, 2022, to the current date for the East Region.
- Formula:
=SUMIFS(E4:E11, C4:C11, ">="&B14, C4:C11, "<="&TODAY(), D4:D11, C14)
5. Method-5: Combination of SUM and IF Functions
- Functions Used:
SUM
,IF
- Purpose: Calculating total sales for the East Region between specific dates using a combination of functions.
- Formula:
=SUM(IF((C4:C11)>=B14, IF((C4:C11)<=C14, IF(D4:D11=D14, E4:E11))))
6. Method-6: Using SUMPRODUCT, MONTH, and YEAR Functions
- Functions Used:
SUMPRODUCT
,MONTH
,YEAR
- Purpose: Summing up sales values for January in the East Region.
- Formula:
=SUMPRODUCT((MONTH(C4:C11)=1)*(YEAR(C4:C11)=2022)*(D4:D11=D14)*E4:E11)
7. Method-7: VBA Code to SUMIF with Different Criteria
- Programming Language: VBA (Visual Basic for Applications)
- Purpose: Using VBA code to calculate total sales between two dates with a specified criterion (East Region).
- Code:
Sub sumdatewithcriteria() Cells(14, 5).Value = Application.WorksheetFunction.SumIfs(Range("E4:E11"), Range("C4:C11"), ">=" & DateValue("1/10/2022"), Range("C4:C11"), "<=" & DateValue("3/20/2022"), Range("D4:D11"), "East") End Sub
In summary, this article provides a comprehensive guide for individuals looking to perform SUMIF operations in Excel based on specified criteria and date ranges. The inclusion of VBA code demonstrates a more advanced approach for automating such calculations. If you have any questions or need further clarification, feel free to ask.